-------------------------------------
-------------------------------------------
--                                                                          --
--                           OCARINA COMPONENTS                             --
--                                                                          --
--                  OCARINA.AADL.PRINTER.COMPONENTS.MODES                   --
--                                                                          --
--                                 B o d y                                  --
--                                                                          --
--               Copyright (C) 2005-2007, GET-Telecom Paris.                --
--                                                                          --
-- Ocarina  is free software;  you  can  redistribute  it and/or  modify    --
-- it under terms of the GNU General Public License as published by the     --
-- Free Software Foundation; either version 2, or (at your option) any      --
-- later version. Ocarina is distributed  in  the  hope  that it will be    --
-- useful, but WITHOUT ANY WARRANTY;  without even the implied warranty of  --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General --
-- Public License for more details. You should have received  a copy of the --
-- GNU General Public License distributed with Ocarina; see file COPYING.   --
-- If not, write to the Free Software Foundation, 51 Franklin Street, Fifth --
-- Floor, Boston, MA 02111-1301, USA.                                       --
--                                                                          --
-- As a special exception,  if other files  instantiate  generics from this --
-- unit, or you link  this unit with other files  to produce an executable, --
-- this  unit  does not  by itself cause  the resulting  executable to be   --
-- covered  by the  GNU  General  Public  License. This exception does not  --
-- however invalidate  any other reasons why the executable file might be   --
-- covered by the GNU Public License.                                       --
--                                                                          --
--                 Ocarina is maintained by the Ocarina team                --
--                       (ocarina-users@listes.enst.fr)                     --
--                                                                          --
------------------------------------------------------------------------------

with Output;

with Ocarina.Nodes;
with Ocarina.Nutils;
with Ocarina.AADL.Printer.Properties;
with Ocarina.AADL.Printer.Identifiers;

package body Ocarina.AADL.Printer.Components.Modes is

   use Output;
   use Ocarina.Nodes;
   use Ocarina.Nutils;
   use Ocarina.AADL.Printer.Properties;
   use Ocarina.AADL.Printer.Identifiers;

   --------------------
   -- Print_In_Modes --
   --------------------

   procedure Print_In_Modes (In_Modes : node_id; Options : output_options) is
      pragma unreferenced (Options);

      List_Node : node_id;
      Mode_List : list_id;
   begin
      if Present (In_Modes) then
         Increment_Indentation;
         Write_Eol;
         Write_Indentation;
         Print_Tokens ((t_in, t_modes, t_left_parenthesis));

         Mode_List := Ocarina.Nodes.Modes (In_Modes);

         if Is_Empty (Mode_List) then
            Print_Token (t_none);
         else
            List_Node := First_Node (Mode_List);

            while Present (List_Node) loop
               case Kind (List_Node) is
                  when k_entity_reference =>
                     Print_Entity_Reference (List_Node);
                  when k_pair_of_entity_references =>
                     Print_Token (t_left_parenthesis);
                     Print_Entity_Reference (First_Reference (List_Node));
                     Write_Space;
                     Print_Token (t_connection);
                     Write_Space;
                     Print_Entity_Reference (Second_Reference (List_Node));
                     Print_Token (t_right_parenthesis);
                  when others =>
                     raise Program_Error;
               end case;

               exit when No (Next_Node (List_Node));
               Print_Token (t_comma);
               Write_Space;

               List_Node := Next_Node (List_Node);
            end loop;

            Decrement_Indentation;
         end if;

         Print_Token (t_right_parenthesis);
      end if;
   end Print_In_Modes;

   ----------------
   -- Print_Mode --
   ----------------

   procedure Print_Mode (Node : node_id; Options : output_options) is
   begin
      Write_Indentation;
      Print_Item_Refined_To (Node);
      Write_Space;

      if Is_Initial (Node) then
         Print_Token (t_initial);
         Write_Space;
      end if;

      Print_Token (t_mode);
      Print_Contained_Property_Associations
        (Ocarina.Nodes.Properties (Node),
         Options);
      Print_Token (t_semicolon);
      Write_Eol;
   end Print_Mode;

   ---------------------------
   -- Print_Mode_Transition --
   ---------------------------

   procedure Print_Mode_Transition
     (Node    : node_id;
      Options : output_options)
   is
      pragma unreferenced (Options);

      List_Node : node_id;
   begin
      Write_Indentation;

      if not Is_Empty (Source_Modes (Node)) then
         List_Node := First_Node (Source_Modes (Node));

         while Present (List_Node) loop
            if List_Node /= First_Node (Source_Modes (Node)) then
               Print_Token (t_comma);
               Write_Space;
            end if;

            Print_Identifier (List_Node);
            List_Node := Next_Node (List_Node);
         end loop;
      end if;

      Write_Space;
      Print_Token (t_left_step_bracket);
      Write_Space;

      if not Is_Empty (Unique_Ports (Node)) then
         List_Node := First_Node (Unique_Ports (Node));

         while Present (List_Node) loop
            if List_Node /= First_Node (Unique_Ports (Node)) then
               Print_Token (t_comma);
               Write_Space;
            end if;

            Print_Entity_Reference (List_Node);
            List_Node := Next_Node (List_Node);
         end loop;
      end if;

      Write_Space;
      Print_Token (t_right_step_bracket);
      Write_Space;

      Print_Identifier (Destination_Mode (Node));
      Print_Token (t_semicolon);
      Write_Eol;
   end Print_Mode_Transition;

end Ocarina.AADL.Printer.Components.Modes;