package core_affinity_with_shared_data
public	
  with multicore_bus_units;
  with Cheddar_Parameters_Properties;
  with Cheddar_Transformation_Properties;

  system implementation core_affinity_with_shared_data.Impl
   subcomponents
    a_process : process  application.Impl;
    cpu       : system   multicore_bus_units::dual_core.impl;
   properties
    Actual_Processor_Binding 
          => (reference(cpu.core1)) 
          applies to a_process.t1;
    Actual_Processor_Binding 
          => (reference(cpu.core2)) 
          applies to a_process.t2;
          
    -- Few specific Cheddar properties to drive the analysis with OSATE2
    --
    Cheddar_Transformation_Properties::Exported_Attribute_Time_Units => MicroSecond;
   	Cheddar_Parameters_Properties::Cheddar_Working_Folder 
	   => "C:\\Users\\singhoff//Desktop//Cheddar_Bin//";
	Cheddar_Parameters_Properties::Cheddar_Install_Folder 
	   => "C:\\Users\\singhoff//Desktop//Cheddar_Bin//";
	   
	Cheddar_Parameters_Properties::Scheduling_Feasibility_Interval => 400;   
	Cheddar_Parameters_Properties::Response_Time_From_Feasibility_Test => true;
	Cheddar_Parameters_Properties::Response_Time_From_Scheduling_Simulation => false;
          
  end core_affinity_with_shared_data.Impl;

  system core_affinity_with_shared_data
  end core_affinity_with_shared_data;

  
  data black
  end black;
  	
  data implementation black.Impl
   properties 
    Concurrency_Control_Protocol => Priority_Ceiling;
  end black.Impl;


  thread ordo_bus
   features
    fe : requires data access black.Impl;
   properties
    Dispatch_Protocol => Periodic;
    Period => 125 ms;
    Deadline => 125 ms;
    Compute_Execution_Time => 1 ms .. 25 ms;
    Priority => 10 ;
  end ordo_bus;
  thread implementation ordo_bus.Impl
  end ordo_bus.Impl;

  thread pilotage
   features
    fe : requires data access black.Impl;
   properties
    Dispatch_Protocol => Periodic;
    Period => 250 ms;
    Deadline => 250 ms;
    Compute_Execution_Time => 25 ms .. 25 ms;
    Priority => 8 ;
  end pilotage;
  thread implementation pilotage.Impl
  end pilotage.Impl;

  
  process Application
  end Application;

  process implementation Application.Impl
   subcomponents
    t1 : thread pilotage.Impl;
    t2 : thread ordo_bus.Impl;
    d1 : data   black.impl;    
   connections
  	c1:	data access d1 -> t1.fe;
  	c2:	data access d1 -> t2.fe;
  end Application.Impl;
  
	
end core_affinity_with_shared_data;