package mars_pathfinder 

public 


  data black
  end black;

  data implementation black.Impl
 -- properties 
 --  Concurrency_Control_Protocol => PCP;
  end black.Impl;



  thread tsched_bus
  properties
    Dispatch_Protocol => Periodic;
    Period => 125 ms;
    Deadline => 125 ms;
    Compute_Execution_Time => 1 ms .. 25 ms;
    Priority => 10 ;
  end tsched_bus;
  thread implementation tsched_bus.Impl
  end tsched_bus.Impl;

  thread tdata
  features
    fe : requires data access black.Impl;
  properties
    Dispatch_Protocol => Periodic;
    Period => 125 ms;
    Deadline => 125 ms;
    Compute_Execution_Time => 25 ms .. 25 ms;
    Priority => 9 ;
  end tdata;
  thread implementation tdata.Impl
  end tdata.Impl;
  
  thread tcontrol
  features
    fe : requires data access black.Impl;
  properties
    Dispatch_Protocol => Periodic;
    Period => 250 ms;
    Deadline => 250 ms;
    Compute_Execution_Time => 25 ms .. 25 ms;
    Priority => 8 ;
  end tcontrol;
  thread implementation tcontrol.Impl
  end tcontrol.Impl;

  thread tradio
  properties
    Dispatch_Protocol => Periodic;
    Period => 250 ms;
    Deadline => 250 ms;
    Compute_Execution_Time => 25 ms .. 25 ms;
    Priority => 7 ;
  end tradio;
  thread implementation tradio.Impl
  end tradio.Impl;

  thread tvideo
  properties
    Dispatch_Protocol => Periodic;
    Period => 250 ms;
    Deadline => 250 ms;
    Compute_Execution_Time => 25 ms .. 25 ms;
    Priority => 6 ;
  end tvideo;
  thread implementation tvideo.Impl
  end tvideo.Impl;

  thread tmesure
  features
    fe : requires data access black.Impl;
  properties
    Dispatch_Protocol => Periodic;
    Period => 5000 ms;
    Deadline => 5000 ms;
    Compute_Execution_Time => 50 ms .. 50 ms;
    Priority => 5 ;
  end tmesure;
  thread implementation tmesure.Impl
  end tmesure.Impl;

  thread tforecast
  features
    fe : requires data access black.Impl;
  properties
    Dispatch_Protocol => Periodic;
    Period => 5000 ms;
    Deadline => 5000 ms;
    Compute_Execution_Time => 50 ms .. 75 ms;
    Priority => 4 ;
  end tforecast;
  thread implementation tforecast.Impl
  end tforecast.Impl;



  process Application
  end Application;

  process implementation Application.Impl
  subcomponents
    tsched_bus : thread tsched_bus.Impl;
    tdata : thread tdata.Impl;
    tcontrol : thread tcontrol.Impl;
    tradio : thread tradio.Impl;
    tvideo : thread tvideo.Impl;
    tmesure : thread tmesure.Impl;
    tforecast : thread tforecast.Impl;
    black  : data   black.Impl;  
  connections
    cx1 : data access black -> tdata.fe;
    cx2 : data access black -> tcontrol.fe;
    cx3 : data access black -> tmesure.fe;
    cx4 : data access black -> tforecast.fe;
  end Application.Impl;


  processor cpu
  properties
    Scheduling_Protocol=>(POSIX_1003_HIGHEST_PRIORITY_FIRST_PROTOCOL);
  end cpu;

  system mars
  end mars;

  system implementation mars.Impl
  subcomponents
    process1 : process application.Impl;
    cpu1 : processor cpu;
  properties
    Actual_Processor_Binding => (reference (cpu1)) applies to process1;
  end mars.Impl;

end mars_pathfinder;