------------------------------------------------------------------------------
------------------------------------------------------------------------------
-- Cheddar is a GNU GPL real time scheduling analysis tool.
-- This program provides services to automatically check performances
-- of real time architectures.
--
-- Copyright (C) 2002-2010,  by Frank Singhoff, Alain Plantec, Jerome Legrand
--
-- The Cheddar project was started in 2002 by
-- the LISyC Team, University of Western Britanny.
--
-- Since 2008, Ellidiss technologies also contributes to the development of
-- Cheddar and provides industrial support.
--
-- This program is free software; you can redistribute it and/or modify
-- it under the terms of the GNU General Public License as published by
-- the Free Software Foundation; either version 2 of the License, or
-- (at your option) any later version.
--
-- This program is distributed in the hope that it will be useful,
-- but WITHOUT ANY WARRANTY; without even the implied warranty of
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
-- GNU General Public License for more details.
--
-- You should have received a copy of the GNU General Public License
-- along with this program; if not, write to the Free Software
-- Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
--
--
-- Contact : cheddar@listes.univ-brest.fr
--
-----------------------------------------------------------------------------
-- Last update :
--    $Rev: 523 $
--    $Date: 2012-09-26 15:09:39 +0200 (Wed, 26 Sep 2012) $
--    $Author: fotsing $
------------------------------------------------------------------------------
------------------------------------------------------------------------------

with Ada.Numerics.Generic_Elementary_Functions;

package body Random_Tools is

   function Get_Rand_Parameter
     (Min  : in Natural;
      Max  : in Natural;
      Seed : in Generator)
      return Natural
   is

      Aux : Double;
      Res : Natural;

   begin
      Aux := Double (Random (Seed)) * (Double (Max) - Double (Min)) +
             Double (Min);
      Res := Natural (Aux);

      if (Res < Min) or (Res > Max) then
         raise Constraint_Error;
      end if;

      return Res;
   end Get_Rand_Parameter;

   function Get_Rand_Parameter
     (Min  : in Double;
      Max  : in Double;
      Seed : in Generator)
      return Double
   is
      Res : Double := 0.0;

   begin
      Res := Double (Random (Seed)) * (Max - Min) + Min;

      if (Res < Min) or (Res > Max) then
         raise Constraint_Error;
      end if;

      return Res;
   end Get_Rand_Parameter;

   -- generate poisson inter arrival time (different from 0)
   --
   function Get_Exponential_Time
     (Arrival_Rate : in Double;
      Seed         : in Generator)
      return         Double
   is
      Result : Double;
   begin

      Result := -1.0 / Arrival_Rate * Log (Double (Random (Seed)));

      return (Result);
   end Get_Exponential_Time;

   -- generate a uniform distribution of task utilizations
   --
   function Gen_UUniFast
     (n : in Integer;		-- Number of task
      U : in Float)		-- Processor utilization
      return Float_Array	-- Float array of task utilizations
   is
      type Value_Type is new Float;
      package Value_Functions is new Ada.Numerics.Generic_Elementary_Functions (Value_Type);
      use Value_Functions;

      utilizations_array : Float_Array(0..n-1);

      G : Generator;
      sumU : Float;
      nextSumU : Value_Type;
   begin
      Reset(G);
      sumU := U;
      for i in 1..n-1 loop
         nextSumU := Value_Type(sumU) * Value_Type(Random(G))**Value_Type(1.0/(n-i));
         utilizations_array(i-1) := sumU - Float(nextSumU);
         sumU:= Float(nextSumU);
      end loop;
      utilizations_array(n-1) := sumU;
      return utilizations_array;
   end Gen_UUniFast;

   -- generate a uniform distribution of task utilizations
   --
   function Gen_UUniFast
     (n : in Integer;		-- Number of task
      U : in Integer)		-- Processor utilization
      return Integer_Array	-- Integer array of task utilizations
   is
      type Value_Type is new Float;
      package Value_Functions is new Ada.Numerics.Generic_Elementary_Functions (Value_Type);
      use Value_Functions;

      utilizations_array : Integer_Array(0..n-1);

      G : Generator;
      sumU : Float;
      nextSumU : Value_Type;
   begin
      Reset(G);
      sumU := Float(U);
      for i in 1..n-1 loop
         nextSumU := Value_Type(sumU) * Value_Type(Random(G))**Value_Type(1.0/(n-i));
         utilizations_array(i-1) := Integer(float'Floor(sumU - Float(nextSumU)));
         sumU:= Float(nextSumU);
      end loop;

      utilizations_array(n-1) := Integer(U);
      for i in 0..n-2 loop
         utilizations_array(n-1) := utilizations_array(n-1) - utilizations_array(i);
      end loop;

      return utilizations_array;
   end Gen_UUniFast;
end Random_Tools;